Gogoratu datorren asteko asteazkena festa delako, laborategirik ez dugula izango. Kalterik izan ez dezazuen 14. praktikari dagokiona ostegun honetan egingo dugu:
Zerrenda pasatu dugu. Deitutako 24en artean 8 ez dira etorri (zehaztapen gehiago eGela zerbitzuan)
Aguirre Perez de Albeniz, Iker
Auzokoa Pagazaurtundua, Paul
Bayón Calvo, Garikoitz
de Miguel Murillo, Celia
Fernández López, Adrián Ginés
Gutierrez Barrencua, Oier
Sanjuan Malaxechevarria, Beñat
Zalduegi Orue, Oier
Proiektuaren J. aukera egin dugu ondoko hau aplikatuz: FITXATEGIEN GAINEKO ERAGIKETAK. Ondoko lan hauek egiteko, batzutan fitxategi laguntzaile bat erabiliko da eta beste batzuetan fitxategi-array (F→A) eta array-fitxategi (A→F) eragiketak erabiliko dira. Eragiketak hauek izango dira:
Bilaketa, futbolari baten izena teklatuz eman eta fitxategian bilatuz erregistro osoa programa nagusira itzuli [Hau egin dugu]
Ezabaketa, elementu bat (edo gehiago) fitxategiaren erdi aldean kentzeko [Hau egin dugu]
Txertaketa, elementu bat (edo gehiago) fitxategiaren erdi aldetik tartekatzeko [Hau ez]
Gehiketa, elementu bat (edo gehiago) fitxategiaren bukaeran gehitzeko [Hau ez]
Aldaketa, elementu baten (edo gehiagoren) balioa aldatzeko fitxategian [Hau ez]
Proiektuaren J. aukera garatzeko programa nagusian idatzi behar den kodea, non zuen programetan kolorerik ez duzuen marraztu behar pantailan:
...
end;
'J': begin
clrscr;
textcolor(LightRed);
writeln('Bilduma-fitxategitik kromo bat kendu eta beste kromo bat txertatu');
writeln('"J_aukera.exe" programa exekutagarriaren funtzionalitatea hemen kokatu');
textcolor(LightGray);
writeln;
clrscr;
writeln;
writeln('J aukeraren hasieran, hauxe da bildumaren egoera:');
TaulaBezalaErakutsi(sFitxIzen);
writeln('Bilduma osoaren kromo kopurua: ', fniZenbatKromo(sFitxIzen));
writeln;
writeln('J aukeran aurrera egiteko RETURN sakatu...');
readln;
writeln;
writeln('Fitxategi laguntzaile bat erabiliz, kromo bat ezabatuko da bildumatik');
writeln('---------------------------------------------------------------------');
write('Bildumatik kenduko den jokalariaren izena: ');
readln(sJokalaria);
writeln;
JokalariaBilatu(sFitxIzen, sJokalaria, rdKromoBat); { rdKromoBat irteerakoa }
if rdKromoBat.iZenbakia = -1 then
writeln('ERROREA!! "', sJokalaria, '" ez da aurkitu')
else
begin
KromoBatErakutsi(rdKromoBat);
iBerePosizioa := fniPosizioaZehaztu(sFitxIzen, sJokalaria);
iNorainoBai := iBerePosizioa -1;
writeln('0-tik hasita 1. zatiaren amaiera: ', iNorainoBai, ' (posizio hau barne, RETURN sakatu)');
readln;
KromoBatFitxategitikKendu(sFitxIzen, iNorainoBai);
writeln;
writeln('"', upcase(sJokalaria), '" jokalaria kendu ondoren, hauxe da bildumaren egoera:');
TaulaBezalaErakutsi(sFitxIzen);
writeln('Bilduma osoaren kromo kopurua: ', fniZenbatKromo(sFitxIzen));
writeln;
writeln;
writeln('ARRAY laguntzaile bat erabiliz, kromo berri bat txertatuko da bilduman');
writeln('----------------------------------------------------------------------');
iIdaztekoAzkenPosizioa := fniZenbatKromo(sFitxIzen); { filesize }
repeat
write('Txertaketaren helburuko posizioa eman (0 eta ', iIdaztekoAzkenPosizioa, ' arteko balioa): ');
readln(iNonTxertatu);
until (iNonTxertatu >= 0) and (iNonTxertatu <= iIdaztekoAzkenPosizioa);
writeln('Bilduman txertatuko den kromo berriaren datuak jaso');
KromoBerriarenDatuakJaso(rdKromoBat);
writeln;
if iNonTxertatu = iIdaztekoAzkenPosizioa then { gehiketa bat da}
KromoaFitxategiarenBukaeran(sFitxIzen, rdKromoBat)
else { txertaketa bat da}
KromoBatFitxategianTxertatu(sFitxIzen, iNonTxertatu, rdKromoBat);
writeln;
writeln('"', upcase(rdKromoBat.sIzena), '" jokalaria txertatu ondoren, hauxe da bildumaren egoera:');
TaulaBezalaErakutsi(sFitxIzen);
writeln('Bilduma osoaren kromo kopurua: ', fniZenbatKromo(sFitxIzen));
writeln;
writeln('Ikusi zenbakiak txarto daudela. Azken urratsarekin jarraitzeko RETURN sakatu');
readln;
writeln;
writeln('J aukeratik irten aurretik jokalari guztien zenbakiak eguneratuko dira');
JokalarienZenbakiakEguneratu(sFitxIzen);
TaulaBezalaErakutsi(sFitxIzen);
writeln('Bilduma osoaren kromo kopurua: ', fniZenbatKromo(sFitxIzen));
writeln;
end; { else, datu-fitxategirik bada }
end;
'K': begin
clrscr;
textcolor(LightRed);
writeln('Lantaldeak proposatutako duen eta irakasleak onartutako duen lana');
writeln('Blogeko "Proiektua aberasteko ideiak (menuaren K aukera)" artikulua ikusi');
textcolor(LightGray);
writeln;
end;
...
Dagoeneko zuen izenak eta abizenak idatzi dituzue Proiektuaren taldekideak artikuluan aipatzen den taulan, norbait falta bada edo zeozer zuzendu behar bada e-posta bat idatz egidazue
program ErregistroenFitxategiaSortuEtaIkusi;
const
sBIDEA = 'C:\NereKarpeta\';
type
tsKate249 = string[249]; { fitxategiaren izena luzea izan daitekeelako }
tsKate15 = string[15];
trdIkaslea = record
sNor: tsKate15;
rNota: real;
end;
tfrdIkasleak = file of trdIkaslea;
{ sFitxIzen katea ezaguna da programa nagusian eta prozedura honetan }
{ izena ez da aldatuko, horregatik sarrerako parametroa da prozeduran }
procedure FitxategiaSortuEtaBete(sFitxIzen: tsKate249);
var
f: tfrdIkasleak;
rdElem: trdIkaslea;
iKont: integer;
iZenbat: integer;
begin
assign(f, sFitxIzen); { fitxategia uztartu }
rewrite(f); { fitxategia sortu eta existitzekotan datuz hustu }
repeat
write('Zenbat ikasle dira? ');
readln(iZenbat);
until iZenbat > 0;
for iKont:=1 to iZenbat do
begin
write(iKont:10, '. ikaslearen izena eman: ');
readln(rdElem.sNor); { erregistroaren eremu bat teklatuz irakurri }
write(iKont:10, '. ikaslearen nota eman: ');
readln(rdElem.rNota); { erregistroaren eremu bat teklatuz irakurri }
write(f, rdElem); { elementu bat (erregistro bat) fitxategia idatzi }
end;
close(f); { fitxategia itxi }
end;
{ sFitxIzen katea ezaguna da programa nagusian eta prozedura honetan }
{ izena ez da aldatuko, horregatik sarrerako parametroa da prozeduran }
procedure FitxategiaIkusi(sFitxIzen: tsKate249);
var
f: tfrdIkasleak;
rdElem: trdIkaslea;
begin
assign(f, sFitxIzen); { fitxategia uztartu }
reset(f); { fitxategia existitzen bada ireki }
while not eof(f) do { fitxategiaren bukaeran ez gauden bitartean... }
begin
read(f, rdElem); { elementu bat (erregistro bat) fitxategitik irakurri }
{ erregistroaren eremu banaren edukia pantailaratu }
writeln(filepos(f):10, '. ikaslearen izena: ', rdElem.sNor);
writeln(filepos(f):10, '. ikaslearen nota: ', rdElem.rNota:0:2);
end;
close(f);
end;
{ sFitxIzen katea ezaguna da programa nagusian eta prozedura honetan }
{ izena ez da aldatuko, horregatik sarrerako parametroa da prozeduran }
function fnMediaKalkulatu(sFitxIzen: tsKate249): real;
var
f: tfrdIkasleak;
rdElem: trdIkaslea;
rMetatua: real;
begin
assign(f, sFitxIzen); { fitxategia uztartu }
reset(f); { fitxategia existitzen bada ireki }
rMetatua := 0.0;
while not eof(f) do { fitxategiaren bukaeran ez gauden bitartean... }
begin
read(f, rdElem); { elementu bat (erregistro bat) fitxategitik irakurri }
{ nota bat gehiago pilatu rMetatua batukarian }
rMetatua := rMetatua + rdElem.rNota;
end;
fnMediaKalkulatu := rMetatua / filesize(f);
close(f);
end;
{ Hiru fitxategien izenak ezagunak direlako programa nagusian eta }
{ prozedura honetan aldatzen ez direlako sarrerako parametroak dira }
procedure BiFitxategiBerriSortu( sFitxIzen: tsKate249;
sFitxIzenAprob: tsKate249;
sFitxIzenSuspn: tsKate249);
var
f, f_A, f_S: tfrdIkasleak;
rdElem: trdIkaslea;
begin
assign(f, sFitxIzen);
reset(f);
assign(f_A, sFitxIzenAprob);
rewrite(f_A);
assign(f_S, sFitxIzenSuspn);
rewrite(f_S);
while not eof(f) do
begin
read(f, rdElem);
if rdElem.rNota >= 5.0 then
write(f_A, rdElem)
else
write(f_S, rdElem)
end;
close(f);
close(f_A);
close(f_S);
end;
{=============Programa nagusia eta programa nagusiko aldagaiak=============}
var
sFitxIzen: tsKate249;
rBBA: real;
sFitxIzenAprob: tsKate249;
sFitxIzenSuspn: tsKate249;
begin
writeln;
write('Eman fitxategiaren izena, adibidez (31Taldea): ');
readln(sFitxIzen);
//sFitxIzen := sBIDEA + sFitxIzen + '.dat'; (* edo hurrengoa *)
sFitxIzen := concat(sBIDEA, sFitxIzen, '.dat'); (* edo aurrekoa *)
writeln('==>', sFitxIzen, '<== bidea eta luzapena programak gehituta');
writeln;
writeln('Fitxategiaren datuak jasotzen...');
FitxategiaSortuEtaBete(sFitxIzen);
writeln;
writeln('Fitxategi osoaren datuak:');
FitxategiaIkusi(sFitxIzen);
writeln;
rBBA := fnMediaKalkulatu(sFitxIzen);
write('Nota guztien batezbesteko aritmetikoa: ', rBBA:0:2, ' puntu');
writeln;
sFitxIzenAprob:= sBIDEA + 'Aprobatuak.dat';
sFitxIzenSuspn:= sBIDEA + 'Suspendituak.dat';
BiFitxategiBerriSortu(sFitxIzen, sFitxIzenAprob, sFitxIzenSuspn);
writeln;
writeln('Aprobatuen datuak:');
FitxategiaIkusi(sFitxIzenAprob);
writeln;
writeln('Suspendituen datuak:');
FitxategiaIkusi(sFitxIzenSuspn);
writeln;
writeln('=======================');
writeln('RETURN sakatu amaitzeko');
write ('=======================');
readln;
end.
12. ASTEA | laborategi/mintegian egin denaren haritik. Erregistroen fitxategi bat daukagula (bi eremu: sNor katea eta rNota zenbakia) ondoko hiru lan hauek laster burutu ahalko dituzu:
Ikasle baten izena teklatuz eman eta bilatu; ikaslea aurkitu ondoren bere nota aldatu, nota berria nota guztien batezbesteko aritmetikoa izan dadin
Nota maximoa eta nota minimoa zehaztu; nota maximoa eta nota minimoa elkar trukatu
Bi fitxategi sortu: batezbestekoaren gainetik daudenen fitxategia eta batezbestekoaren azpitik daudenen fitxategia
Proiektua: hobekuntzak aitortu (2024) zereginaren bitartez zuen proiektuaren menuak izango duen K aukera proposatu (Entregatze-data: 2024ko apirilaren 18an, 23:59tan, larunbata)
Ondoko hau urrunago dago: Proiektua amaiturik (2024) zereginaren bitartez zuen proiektua entregatu, hots, menuaren J eta K aukerak programatu (Entregatze-data: 2024ko maiatzaren 1ean, 23:59tan, astelehena)
Zerrenda pasatu dugu. Deitutako 24en artean 8 ez dira etorri (zehaztapen gehiago eGela zerbitzuan)
Gaurko helburua bikoitza da:
Erregistroen arrayekin lan egitea
Erregistroen fitxategi bat sortzea
Erregistroen array bat
Erregistroen array baten adibidea egin dugu. Konkretuki 11. astea | erregistroen bektore baten elementuak ezabatu artikulutik abiatuta, zerbait laburrago egin dugu. Bi eremu (sIzena katea eta iAdina zenbaki osoa) dituen erregistroetako arrayarekin lan egin dugu eragiketa hauek burutuz:
Zerrenda datuz bete (errazagoa izan dadin elementuen izenak errepika daitezke)
Zerrendaren edukia pantailaratu
Ikasle bat bilatu eta bere informazioa pantailaratu
Adin guztien batezbesteko aritmetikoa kalkulatu
Hainbat elementu zerrendatik ezabatu (bietariko bat egin dugu):
Adin txikiko elementuak (media baino txikiagoak direnak) zerrendatik kendu, ondorioz hasierako zerrenda aldatua suertatuko da
A edo a letratik hasten diren izenen elementuak zerrendatik kendu, ondorioz hasierako zerrenda aldatua suertatuko da
Zerrenda berriaren edukia pantailaratu
Erregistroen fitxategi bat
Erregistroen fitxategi bat (bi eremu: sNor katea eta rNota zenbaki erreala) sortu dugu eta ondoren bere edukia pantailan erakutsi dugu. Hona hemen programaren kodea urratsez-urrats azalduta:
program ErregistroenFitxategiaSortuEtaIkusi;
type
tsKate249 = string[249]; { fitxategiaren izena luzea izan daitekeelako }
tsKate15 = string[15];
trdIkaslea = record
sNor: tsKate15;
rNota: real;
end;
tfrdIkasleak = file of trdIkaslea;
{ sFitxIzen katea ezaguna da programa nagusian eta prozedura honetan }
{ izena ez da aldatuko, horregatik sarrerako parametroa da prozeduran }
procedure FitxategiaSortuEtaBete(sFitxIzen: tsKate249);
var
f: tfrdIkasleak; // file datu-motako aldagaia
rdElem: trdIkaslea; // fitxategiaren elementua
begin
end;
{ sFitxIzen katea ezaguna da programa nagusian eta prozedura honetan }
{ izena ez da aldatuko, horregatik sarrerako parametroa da prozeduran }
procedure FitxategiaIkusi(sFitxIzen: tsKate249);
var
f: tfrdIkasleak; // file datu-motako aldagaia
rdElem: trdIkaslea; // fitxategiaren elementua
begin
end;
{=============Programa nagusia eta programa nagusiko aldagaiak=============}
var
sFitxIzen: tsKate249;
begin
writeln;
writeln('Eman fitxategiaren izena, adibidez (C:\NereKarpeta\31Taldea.dat): ');
readln(sFitxIzen);
writeln('===>', sFitxIzen, '<===');
writeln;
writeln('Fitxategiaren datuak jasotzen...');
FitxategiaSortuEtaBete(sFitxIzen);
writeln;
writeln('Fitxategiaren datuak:');
FitxategiaIkusi(sFitxIzen);
writeln;
writeln('=======================');
writeln('RETURN sakatu amaitzeko');
write ('=======================');
readln;
end.
Proiektua dela eta, hirukoteak osoatu dituzue eta orain hau egizue:
Azterketa bat, eredu bat enuntziatua astiro irakurri eta azpimarratu ulertzen ez dituzuen hitzak (adibidez fitxategi)
Azterketa bat, beste eredu bat enuntziatua astiro irakurri eta azpimarratu ulertzen ez dituzuen hitzak (adibidez fitxategi). Bide batez, konturatu zaitez bi azterketa enuntzituek dituzten antzekotasunak
Esan bezala, proiektuak taldeka burutuko dira eta taldeen antolaketa ikasleen esku geratuko da. Taldeak hirukoteka osatuko dira beheko taulan ikasle bakoitzaren izena idatziz:
Udaberriko oporralditik itzultzean, apirilaren 10eko laborategi egunean, irakasleak proiektuaren enuntziatua azaldu zuen eta erabiliko diren unitateei dagozkien interfazeen deskribapenak egin zituen (unitateak lau hauek dira: maia_uzta, bilduma21, bilduma30 eta bilduma39).
Ondoren, bide hau irekitzat ematen da:
Bideak hiru munarri ditu:
Proiektuaren baliabideak unitate batean garaturik daude, apirilaren 10ean unitatearen funtzionamendua laborategian ikusi da. Zuen lana: etxeko ordenadorean unitate baten funtzionamendua frogatzea, bi adibide: itsas-bataila (i) eta itsas-bataila (ii)
Proiektuari gehituko dizkiozuen hobekuntzen aitorpena, gehien jota apirilaren 18rako (ostegunerako) bete behar duzue Proiektua: hobekuntzak aitortu (2024) izeneko zereginari erantzunez
Proiektua garatu, gehien jota maiatzaren 1erako (astelehenerako) bukatu beharko duzue eta bere entrega Proiektua amaiturik (2024) izeneko zereginaren bitartez egingo duzue
Goiko irudia begiratu, ikusten duzue bidea bukatzen den tontorraren ostean beste tontor bat agertzen dela? Ba bai, halaxe da, oraindik zerbait gehiago falta da, hau:
Hirugarren munarrian entregatu duzuen lanaren gaineko azterketa bat pasatu beharko duzue 15. asteko praktika egunean (maiatzaren 8an). Lantaldearen kide bakoitzak froga bera egin beharko du bakarka, ordenagailuaren aurrean garatutako proiektuaren gaineko ariketa bat izango da.
Entregak
Goiko irudian proiektuaren urratsak erakusten badira, hurrengo irudi honetan urrats bakoitzean zer entregatuko duzuen erakusten da:
Proiektuari laguntzen dion unitate sorta: zuen etxeko ordenagailuan frogatu. Entregarik ez dago, baina arazorik baduzue tutoretza bat eska ezazue
Proiektuari gehituko dizkiozuen hobekuntzen aitorpena: txosten idatzi bat
Proiektua garatu: txosten bat idatzi bat eta programa bat (programa iruzkindu)
Proiektuaren gaineko bakarkako froga: programa bat
Ikasketa prozesuan ikasleak ariketa laburrak egin beharko ditu kontzeptu zehatz bat edo beste ikaste aldera. Baina, azken azterketa, bilduma bat delako, ariketa handia izango da. Horregatik, komenigarria da azken azterketaren neurriko proiektu bat urratsez urrats ikasturtearen zehar garatzea.
Proiektua mintegiko (12+24 orduak) eskolekin lotuta dago, batez ere gelaz kanpoko 24 orduekin lotuta dago.
Proiektua bideratzekoInformatika ☆ 2023-24 | proiektua izeneko bloga erabiliko dugu, non 2022-23 ikasturteko azterketa pare baten gaineko ariketak erakusten diren. Kromo-biltegi kasu bat aitzakiz hartuz, datuen multzoak prozesatzea izango da proiektuaren helburua.
Proiektuaren garapenaren urrats bakoitzean, ikasleak argi beharko du izan zer da dagoeneko dakiena eta zer ikasiko duen urrats horretan. Urrats bakoitzaren hasieran, adibidez, honelako informazioa jasoko du ikasleak:
ZER DAKIDAN: Badakit testuak eta konstanteen balioak pantailan idazten.
ZER IKASIKO DUDAN: ReadLn prozedurari esker, teklatuaren bitartez, balio bat aldagai batean gordetzen ikasiko dut. Esleipena operazioaren bitartez aldagai batean balio jakin bat gordetzen ikasiko dut.
Azkeneko laborategi egunean, maiatzaren 8an, proiektua gaitzat harturik ikasleak azterketa bat pasatu beharko du.
01 Prozesaketa (osorik prozesaketu), arrayaren elementu guztiei prozesu jakin bat aplikatu (ikus 01_Prozesaketa.pas programa). Klasean adibide bat egin dugu: array bat datuz bete eta array horren edukia erakutsi
asTaula hiru dimentsiotako taula bat da, kateak gorde ditzakeen asTaula arrayak 40 errenkada eta 3 zutabe ditu. Errenkada bakoitza ikasle bati dagokio: Errenkadaren lehen zutabean izena biltegitzen da, bigarrenean abizena eta hirugarren zutabean ikaslearen nota gordetzen da (hirurak string[19] datu-motakoak). Teoriako blogean gehiago...
Gehienez 25 elementu gordetzeko gai den array batekin lan egingo dugu. Arrayaren elementuak zenbaki errealak izango dira.
Datua den zenbaki erreal bat arrayean gorde aurretik, frogatu beharra dago errepikaturik ez dela egongo. Horretarako, teoriako blogearen 9. astea | bilaketa sekuentzialaren aplikazio bat programara jo eta bertako BilaketaLineala izeneko funtzioa erabili gure behar izanetara egokituz, hots, erabili beharko dituen moldapenak eginez.
{ Zenbaki erreal desberdinez array bat elikatu ondoren, minimoaren eta }
{ maximoaren posizioak lortu bi haien arteko lekuak elkar trukatzeko. }
program ElkarTrukatu;
uses
crt;
const
iBEHEMUGA = 1;
iGOIMUGA = 20;
type
tarZerrenda = array[iBEHEMUGA..iGOIMUGA] of real;
function fniBilatu(const arZerrenda: tarZerrenda;
iZenbat: integer;
rGakoa: real): integer;
var
iKontagailu: integer;
boAurkitua: boolean;
begin
iKontagailu := iBEHEMUGA;
boAurkitua := FALSE;
while (iKontagailu <= iZenbat) and not boAurkitua do
begin
if arZerrenda[iKontagailu] = rGakoa then
begin
writeln(rGakoa:0:1, ' balioa ', iKontagailu:2, ' posizoan dago!');
boAurkitua := TRUE;
end
else
begin
writeln(rGakoa:0:1, ' bilatzen, ', iKontagailu:2, '. elementuarekin ez du bat egiten, hurrengoa aztertu!');
iKontagailu := iKontagailu + 1;
end;
end;
if boAurkitua then
begin
fniBilatu := iKontagailu;
writeln(rGakoa:0:1, ' balioa badago arrayan. Beste balio batekin saiatu!');
end
else
begin
fniBilatu := 0;
writeln(rGakoa:0:1, ' balioa berria da eta ', iZenbat+1, '. posizioan kokatuko da');
end;
writeln;
end;
procedure ArrayaDatuDesberdinezBete(var arZerrenda: tarZerrenda;
var iLuzera: integer);
var
iKont: integer;
rZbk: real;
begin
randomize;
iLuzera := random(iGOIMUGA) + 1; { iBEHEMUGA eta iGOIMUGA arteko balioak }
//writeln('iLuzera=', iLuzera);
arZerrenda[iBEHEMUGA] := random(10) + 0.1*random(2); { 0.0, 0.1, 1.0, 1.1, ... 8.0, 8.1, 9.0, 9.1 arteko balioak }
writeln('1. datua = ', arZerrenda[iBEHEMUGA]:0:1);
writeln;
for iKont:=iBEHEMUGA+1 to iLuzera do
begin
repeat
rZbk := random(10) + 0.1*random(2); { 0.0, 0.1, 1.0, 1.1, ... 8.0, 8.1, 9.0, 9.1 arteko balioak }
until fniBilatu(arZerrenda, iKont-1, rZbk) = 0;
arZerrenda[iKont] := rZbk;
end;
end;
procedure ArrayarenEdukiaIkusi(const arZerrenda: tarZerrenda;
iLuzera: integer);
var
iKont: integer;
begin
for iKont:=iBEHEMUGA to iLuzera do
begin
writeln(iKont:10, '. elementua = ', arZerrenda[iKont]:0:1);
end;
writeln;
end;
function fniArrayarenMaximoaNon(const arZerrenda: tarZerrenda;
iLuzera: integer): integer;
var
iKont, iMaxNon: integer;
rMaximoa: real;
begin
iMaxNon := iBEHEMUGA;
rMaximoa := arZerrenda[iBEHEMUGA];
for iKont:=iBEHEMUGA+1 to iLuzera do
begin
if arZerrenda[iKont] > rMaximoa then
begin
iMaxNon := iKont;
rMaximoa := arZerrenda[iKont];
end;
end;
fniArrayarenMaximoaNon := iMaxNon;
end;
function fniArrayarenMinimoaNon(const arZerrenda: tarZerrenda;
iLuzera: integer): integer;
var
iKont, iMinNon: integer;
rMinimoa: real;
begin
iMinNon := iBEHEMUGA;
rMinimoa := arZerrenda[iBEHEMUGA];
for iKont:=iBEHEMUGA+1 to iLuzera do
begin
if arZerrenda[iKont] < rMinimoa then
begin
iMinNon := iKont;
rMinimoa := arZerrenda[iKont];
end;
end;
fniArrayarenMinimoaNon := iMinNon;
end;
procedure ElementuakTrukatu(var arZerrenda: tarZerrenda;
iPosMax: integer;
iPosMin: integer);
var
rLaguntzailea: real;
begin
rLaguntzailea := arZerrenda[iPosMax];
arZerrenda[iPosMax] := arZerrenda[iPosMin];
arZerrenda[iPosMin] := rLaguntzailea;
end;
{ ------------------------- Programa Nagusia ------------------------- }
var
arZerrenda: tarZerrenda;
iLuzera, iPosMax, iPosMin: integer;
cErantzuna: char;
begin
repeat
clrscr;
writeln('----------------------------------------');
ArrayaDatuDesberdinezBete(arZerrenda, iLuzera);
writeln('Hasierako datuak:');
ArrayarenEdukiaIkusi(arZerrenda, iLuzera);
iPosMax := fniArrayarenMaximoaNon(arZerrenda, iLuzera);
iPosMin := fniArrayarenMinimoaNon(arZerrenda, iLuzera);
writeln('Maximoa ', iPosMax, ' posizioan');
writeln('Minimoa ', iPosMin, ' posizioan');
writeln('Elkar trukatu ondoren: ');
writeln;
ElementuakTrukatu(arZerrenda, iPosMax, iPosMin);
writeln('Datuen trukaketa egin ondoren:');
ArrayarenEdukiaIkusi(arZerrenda, iLuzera);
writeln;
repeat
write('Amaitu nahi duzu? (b/e): ');
cErantzuna := readkey;
writeln(cErantzuna);
cErantzuna := upcase(cErantzuna);
until (cErantzuna = 'B') or (cErantzuna = 'E');
until cErantzuna = 'B';
end. { programaren amaiera }
Gehienez 15 elementu gordetzeko gai diren arrayekin lan egingo dugu. Arrayen elementuak zenbaki osoak izango dira.
Programaren balizko exekuzio bat jarraian erakusten da:
{ Zenbaki osoak array batean gorde ondoren, bakoiti eta negatiboak }
{ diren elementuak arraytik kendu (array laguntzaile bat erabiliz). }
program ZenbakiakKendu;
uses
crt;
const
iBEHEMUGA = 1;
iGOIMUGA = 20;
type
taiZerrenda = array[iBEHEMUGA..iGOIMUGA] of integer;
procedure ArrayaAleatoriokiDatuzBete(var aiZerrenda: taiZerrenda;
var iZenbat:integer);
var
iKont: integer;
begin
repeat
write('Zenbat datu dira? (gehienez ', iGOIMUGA, '): ');
readln(iZenbat);
until (iZenbat >= iBEHEMUGA) and (iZenbat <= iGOIMUGA);
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
aiZerrenda[iKont]:= random(40)-20; { -20 eta 19 artek balioak }
end;
end;
procedure ArrayarenEdukiaIkusi(const aiZerrenda: taiZerrenda;
iLuzera: integer);
var
iKont: integer;
begin
for iKont:=iBEHEMUGA to iLuzera do
begin
writeln(iKont:10, '. elementua = ', aiZerrenda[iKont]:3);
end;
writeln;
end;
procedure BakoitiNegatiboakKendu(var aiZerrenda: taiZerrenda;
var iLuzera: integer);
var
iKont, iLuzeraBerria: integer;
aiZerrendaBerria: taiZerrenda;
begin
iLuzeraBerria := 0;
for iKont:=iBEHEMUGA to iLuzera do
begin
if (aiZerrenda[iKont] < 0) and (aiZerrenda[iKont] mod 2 <> 0) then
begin
writeln('Hau saihestu ---> aiZerrenda[', iKont:2,'] = ', aiZerrenda[iKont]:3);
end
else
begin
iLuzeraBerria := iLuzeraBerria + 1;
aiZerrendaBerria[iLuzeraBerria] := aiZerrenda[iKont];
end;
end;
aiZerrenda := aiZerrendaBerria;
iLuzera := iLuzeraBerria;
end;
{ ------------------------- Programa Nagusia ------------------------- }
var
aiZerrenda: taiZerrenda;
iLuzera: integer;
cErantzuna: char;
begin
repeat
clrscr;
writeln('--------------------------------------------');
writeln('Datuak eskuratzen: ');
ArrayaAleatoriokiDatuzBete(aiZerrenda, iLuzera);
writeln('Hasierako datuak: ');
ArrayarenEdukiaIkusi(aiZerrenda, iLuzera);
BakoitiNegatiboakKendu(aiZerrenda, iLuzera);
writeln;
writeln('Bakoiti negatiboak kendu ondoren: ');
ArrayarenEdukiaIkusi(aiZerrenda, iLuzera);
repeat
write('Amaitu nahi duzu? (b/e): ');
cErantzuna := readkey;
cErantzuna := upcase(cErantzuna);
writeln(cErantzuna);
until (cErantzuna = 'B') or (cErantzuna = 'E');
writeln;
writeln;
writeln;
writeln;
until cErantzuna = 'B';
end. { programaren amaiera }
Gehienez 20 elementu gordetzeko gai diren arrayekin lan egingo dugu. Arrayen elementuak zenbaki osoak izango dira.
{ Luzera logikorik ez da erabiltzen hiru arrayak }
{ beti beterik daudela suposatzen delako. }
program HiruArray;
uses
crt;
const
iBEHEMUGA = 1;
iGOIMUGA = 20;
type
taiZenbakiak = array[iBEHEMUGA..iGOIMUGA] of integer;
procedure ArrayakAleatoriokiBete(var aiZenbakiak1: taiZenbakiak;
var aiZenbakiak2: taiZenbakiak);
var
iKont: integer;
begin
randomize;
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
aiZenbakiak1[iKont] := random(40) - 20; { -20 eta 19 arteko balioak }
aiZenbakiak2[iKont] := random(40) - 20; { -20 eta 19 arteko balioak }
end;
writeln;
end;
procedure ArrayaBete(var aiZenbakiak: taiZenbakiak);
var
iKont: Integer;
begin
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
write('Eman ', iKont:2, '. zenbakia: ');
readln(aiZenbakiak[iKont]) ;
end;
writeln;
end;
procedure ArrayaIkusi(const aiZenbakiak: taiZenbakiak);
var
iKont: integer;
begin
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
writeln(iKont:2, '. zenbakia = ', aiZenbakiak[iKont]);
end;
writeln;
end;
procedure ArrayaLortu(const aiX, aiY: taiZenbakiak;
var aiZ: taiZenbakiak);
var
iKont: integer;
begin
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
if aiX[iKont] > aiY[iKont] then
aiZ[iKont] := 1;
if aiX[iKont] = aiY[iKont] then
aiZ[iKont] := 0;
if aiX[iKont] < aiY[iKont] then
aiZ[iKont] := -1;
end;
end;
function fniKontatuZenbatPlus(const aiZ: taiZenbakiak): integer;
var
iKont, iZenbat: integer;
begin
iZenbat := 0;
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
if aiZ[iKont] = 1 then
iZenbat := iZenbat + 1;
end;
fniKontatuZenbatPlus := iZenbat;
end;
function fniKontatuZenbatMinus(const aiZ: taiZenbakiak): integer;
var
iKont, iZenbat: integer;
begin
iZenbat := 0;
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
if aiZ[iKont] = -1 then
begin
iZenbat := iZenbat + 1;
end;
end;
fniKontatuZenbatMinus := iZenbat;
end;
function fniKontatuZenbatZero(const aiZ: taiZenbakiak): integer;
var
iKont, iZenbat: integer;
begin
iZenbat := 0;
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
if aiZ[iKont] = 0 then
begin
iZenbat := iZenbat + 1;
end;
end;
fniKontatuZenbatZero := iZenbat;
end;
procedure HiruKontaketakEgin( const aiZeta: taiZenbakiak;
var iZenbatPlus: integer;
var iZenbatMinus: integer;
var iZenbatZero: integer);
var
iKont: integer;
begin
iZenbatPlus := 0;
iZenbatMinus := 0;
iZenbatZero := 0;
for iKont:=iBEHEMUGA to iGOIMUGA do
begin
case aiZeta[iKont] of
1: begin
iZenbatPlus := iZenbatPlus + 1;
end;
-1: begin
iZenbatMinus := iZenbatMinus + 1;
end;
0: iZenbatZero := iZenbatZero + 1;
end;
end;
end;
{ ------------------------- programa nagusia ------------------------- }
var
aiX, aiY, aiZ: taiZenbakiak;
iZenbatPlus, iZenbatMinus, iZenbatZero: integer;
begin
clrscr;
writeln('aiX eta aiY arrayen datuak aleatorioki hartuko dira');
ArrayakAleatoriokiBete(aiX, aiY);
writeln('aiX arrayaren edukia');
ArrayaIkusi(aiX);
writeln('aiY arrayaren edukia');
ArrayaIkusi(aiY);
writeln;
ArrayaLortu(aiX, aiY, aiZ);
writeln('aiZ arrayaren edukia');
ArrayaIkusi(aiZ);
writeln;
iZenbatPlus := fniKontatuZenbatPlus(aiZ);
iZenbatMinus := fniKontatuZenbatMinus(aiZ);
iZenbatZero := fniKontatuZenbatZero(aiZ);
writeln('Hiru funtzioz...');
writeln('Xi elementuak Yi elementuak baino handiago: ', iZenbatPlus, ' aldiz' );
writeln('Xi elementuak Yi elementuak baino txikiago: ', iZenbatMinus, ' aldiz' );
writeln('Xi elementuak eta Yi elementuak berdinak: ', iZenbatZero, ' aldiz' );
writeln;
HiruKontaketakEgin(aiZ, iZenbatPlus, iZenbatMinus, iZenbatZero);
writeln('Prozedura bakarraz...');
writeln('Xi elementuak Yi elementuak baino handiago: ', iZenbatPlus, ' aldiz' );
writeln('Xi elementuak Yi elementuak baino txikiago: ', iZenbatMinus, ' aldiz' );
writeln('Xi elementuak eta Yi elementuak berdinak: ', iZenbatZero, ' aldiz' );
repeat until keypressed;
end. { programaren amaiera }